flv 2 mp4 - get youtube on the ipod

How to transcode youtube's videos to your iPod

A simple FLV (Flash) to MP4 converter!

also works as an FLV 2 MP4, AVI 2 MP4, WMV 2 MP4, 3GP 2 MP4, ...
in other words, it transcodes any .FLV file from any site (metacafe, google ...) to an MPEG4

Yes yes, i know there are tons of tools already doin' that (like eg iTube)
But, for many reasons i prefer to use a simpler BATCH SCRIPT,
instead of installing other softwares.

Note that this also works for any input format supported by VLC.
Eg: you can quickly convert any FILE from AVI, WMV, MOV, 3GP, DVD

Basically this operation consists of 3 main steps:

1) download the .FLV file from youtube
(very quick & easy if using the firefox's extension called Fast Video Download)

2) use this dos script (it can be easily converted in linux).

C:\> vlc -vvv FILE.FLV :sout="#transcode{fps=25,samplerate=44100,width=320, canvas-height=240, vcodec=mp4v, vb=768, acodec=mp4a, ab=96, channels=2}:standard{access=file,mux=mp4,url=MYFILE.MP4}" vlc:quit

3) drop the MP4 file in iTunes;


---------------
to make life easier

i created my own batch script that converts all the input files in just one command.
this can be used in windows in the ( "send to -->" context menu).
Paste the following code in a new file, and check the VLC path is correct (VLC1=...)

i've created 4 possible VLC locations (VLC1, VLC2 ...) just to use the same script on different boxes.

@ECHO off

SET VLC1="C:\Program Files\vlc\videolan\vlc.exe"
SET VLC2="C:\Programmi\vlc\videolan\vlc.exe"
SET VLC3="C:\VLC\vlc.exe"
SET VLC4="D:\VLC\vlc.exe"
SET VLC=%VLC1%

IF NOT EXIST %VLC% SET VLC=%VLC2%
IF NOT EXIST %VLC% SET VLC=%VLC3%
IF NOT EXIST %VLC% SET VLC=%VLC4%

IF EXIST %VLC% GOTO LOOP

ECHO ERROR! VLC not found
pause

GOTO CLEANUP

:LOOP

IF (%1)==() GOTO CLEANUP

REM IMPORTANT !!
REM
REM in the following lines, the script
REM corrects the filename: replacing all the strange
REM characters, and removing the file extension
REM thus: YOU NEED TO HAVE an .FLV (or .AVI .3GP .XXX)
REM extension in the input filename!

SET FILE1=%1
SET FILE2=%FILE1%
SET FILE2=%FILE2:~0,-5%
SET FILE2=%FILE2:"=%
SET FILE2=%FILE2:'= %
SET FILE2=%FILE2%.mp4
SET FILE2='%FILE2%'

%VLC% -vvv %FILE1% :sout="#transcode{fps=25,samplerate=44100,width=320, canvas-height=240, vcodec=mp4v, vb=768, acodec=mp4a, ab=96, channels=2}:standard{access=file,mux=mp4,url=%FILE2%}" vlc:quit

SHIFT

GOTO LOOP

:CLEANUP

NOTE: the only requirement is the VLC video lan converter .